Синхронизируем время на модуле DS3231 с компьютером


Доброго дня любителям самоделок и просто точных и качественных вещей вроде модуля часов реального времени DS3231. Пора поделиться с вами опытом синхронизации времени между модулем часов и компьютером – чуть ли не единственным способом выставить время более или менее точно. Заходите, почитайте (ну, или видео работы девайса посмотрите).

Зачем всё это нужно?

Начну с вопроса, ответ на который очевиден: что самое важное в любых часах? Разумеется, это точность хода. Какими бы многофункциональными и эстетичными не были любые часы, они – барахло, если идут неточно. Поэтому, если говорить о точности, ни для кого не секрет, что на данный момент модуль DS3231 – один из самых конкурентоспособных модулей на рынке: он относительно дёшев, достаточно точен, в отличие от, например, «доисторического» DS3107, и относительно невелик. Поэтому применение этого модуля в самоделках – абсолютно логичный и предсказуемый шаг. Осталась мелочь – научиться выставлять на нём время достаточно точно и с минимальными трудозатратами. Этим я и хочу поделиться.

Если часы – точные, как часто понадобится синхронизация?

Давайте прикинем: модуль часов имеет заявленную точность до 2 ppm в диапазоне температур от 0 до 40 градусов Цельсия (а в большинстве жилищ температура именно такая).

Что такое «ppm»? PPM – аббревиатура от «Parts Per Million» – «частей на миллион». Возьмём за единицу измерения секунду и посчитаем:

60сек * 60мин *24 часа * 365 дней = 31 536 000 секунд в году.

На каждый из этих миллионов 2 секунды может уходить в ту или иную сторону. 31,5 миллион делим на миллион и умножаем на 2: получаем 63 секунды в год (максимум). Приемлемый вариант? Весьма. Но 1 раз в полгода я бы синхронизировал время, чтобы оно укладывалось в 1 минуту.

Какими способами вообще можно устанавливать время на часах модуля?

Традиционно, начиная с модуля DS3107, время устанавливалось при помощи скетча для Arduino из числа примеров использования библиотеки. Алгоритм такой: открываем скетч, жмём «компилировать и закачать», и при первом запуске контроллера время устанавливается. Остался вопрос: какое время? Откуда Arduino может узнать, какое именно время устанавливать? А очень просто – время компиляции скетча. Однако с таким подходом я вижу несколько недостатков:

  • время компиляции зависит от «мощи» компьютера;
  • время закачивания зависит от скорости передачи скомпилированного скетча в плату Arduino;
  • закачанный скетч – «одноразовый» (устаревает сразу же после закачивания в Arduino).
Как можно «извернуться», чтобы обойти эти ограничения? Ну, например, зная (экспериментально установив) время компилирования, можно «загнать» часы на компьютере на это время вперёд. Потом запустить компиляцию, прошить плату, и время установится. Плюс метода – относительная простота. Минусы – относительно неудобно, относительно неточно, одноразовый способ.

Что ещё можно придумать? Можно, например, выставлять требуемое время в скетче вручную, предусмотреть кнопку, нажатие на которую в нужный момент выставит «руками» указанное время, например, через 2 минуты от текущего момента: пока «зальётся» скетч, пока подготовимся отследить вручную тот самый нужный момент нажатия кнопки, как раз та пара минут и пройдёт. А дальше, глядя на часы в компьютере, дожидаться «того самого» момента, чтобы нажать кнопку. Плюсы – сложнее предыдущего способа, но всё ещё относительно просто, однако точнее, чем первый способ. Минусы – этот способ ещё неудобнее, дольше, всё равно скетч «одноразовый».

Кто виноват и что делать?

Задав себе эти два риторических вопроса, я полез в Интернет искать, кто уже написал синхронизацию времени модуля часов с компьютером. И, как известно, кто ищет – тот всегда находит. Нашёлся вариант с Instructables. В теории всё просто: обычный «батник» парсит текущее полное время, полученное «первым» способом (потому что кроме самого времени нужна ещё и дата), увеличивает время на 2 секунды, и «гоняет» пустой цикл до момента, когда настанет это новое, «плюс_две_секундное», время, чтобы «вышвырнуть» данные в COM порт. Причём «новое плюс_две_секундное» время отслеживается другим способом (через %time%, если кому интересно). Но о «косяках» такого решения позже. Данные, «вышвырнутые» в COM порт, Arduino парсит и после этого устанавливает время в модуле. Вроде всё просто, логично и удобно. Но есть очень нехорошее слово «НО». Всё это писал вроде бы немец, и региональные стандарты в Windows у него отличаются от «наших», а в частности, дробная часть отделяется точкой, а не запятой. При запуске с отечественными региональными стандартами «батник» не работает, потому что в нём время выхода из пустого цикла описывается условием сравнения с XX:XX:XX.xxx. Ну так надо вместо точки поставить запятую – и всё, «я всё починил». А вот и не всё (можете проверить, кто ещё помнит, что за такое зло – программировать в «батниках»). Нужно исправлять «батник» более серьёзно. И я его исправил, используя «маты-перематы» и «мануалку» для DOS. «Батник» исправил, но скетч всё равно не работал – время не устанавливалось. То есть данные в порт слались, Arduino их видел, но «что-то пошло не так».

Давайте взглянем, что шлёт «батник» в Arduino и в каком формате (справочно).

case 83:   //S = second
case 68:   //D = Minute  (Daghigheh in Persian)
case 72:   //H = Hour
case 84:   //T = Day Of Month (Tag in German)
case 77:   /// M = Month
case 74:   /// J = Year (Jahr in German)

Данные шлются в формате S**~D**~H**~T*~M**~J****~, где ~ — 2 байта перевода каретки. Итого, 31 байт. Вроде немного, пришлются данные быстро.

Однако есть и неудобство – как видим, не шлётся день недели. Только день месяца. Для реализации часов с будильниками, зависящими от дней недели, будет «косяк». День недели придётся выставлять «ручками» в скетче, что опять намекает на некоторую «одноразовость» скетча, его неполноценность.

Складывая факторы – неполноценность скетча «с завода», его отказ нормально работать, необходимость исправления «батника» для «наших» широт – я решил разрабатывать всё свое. А раз так, то я могу устранять недостатки и оптимизировать формат данных.

Software и hardware.

Для того, чтобы всё заработало, нужны 2 составляющие: программа для Windows и аппаратно-программная связка Arduino.

Сначала общие данные по протоколу обмена. Коль скоро я стал волен выбирать формат данных для пересылки, я решил, что пересылка 31 байта информации не рациональна, и сократил передаваемые данные до 4 байт. И что, хватило? Что можно поместить в 4 байта? Да, хватило. Поместилось все, что надо. Уверен, многие догадались, что это за 4 байта. Кто не догадался – процитирую фрагмент статьи из Википедии:

UNIX-время (POSIX-время) — система описания моментов во времени, принятая в UNIX и других POSIX-совместимых операционных системах. Определяется как количество секунд, прошедших с полуночи (00:00:00 UTC) 1 января 1970 года (четверг).
UNIX-время представлено целым числом, которое увеличивается с каждой прошедшей секундой без необходимости вычислений для определения года, месяца, дня, часа или минуты для удобства восприятия человеком. Современное UNIX-время согласуется с UTC — отсчет происходит в секундах СИ.


Итак, целое число, хранящее UNIX время, занимает 4 байта, чего хватит до 2 147 483 648 секунд. А потом возможны потенциальные проблемы. Почему потенциальные? Потому что это порог, при достижении которого число может быть интерпретировано, как отрицательное (что и произошло с айфонами многих любопытных товарищей в своё время). Может, но не обязательно будет – зависит от того, растут ли руки программистов из места, предусмотренного природой. Указанное число секунд соответствует 03:14:08 19-янв-2038. До этого времени можно неспешно переходить на 64-битную версию ОС, где время станет храниться в 8-байтной переменной, чего без проблем хватит на следующие 292 миллиарда лет. Существует вероятность, что на наш век этого хватит. А потом придётся обновляться до 128-битной версии UNIX.

Какие проблемы я решил, придя к такому варианту? Первое, сильно снизил количество передаваемых байт, что на миллисекунды увеличивает точность установки времени. Здорово, правда? И второе: я (вероятно) облегчил совместимость с Linux. К моему стыду, я никак не могу привыкнуть к Linux, и пользуюсь в основном только Windows. Для этой самой Windows я могу написать программу пересылки, а для Linux – нет. Но полагаю, что в Linux можно получить значение UNIX-времени намного легче, чем в Windows, и переслать это число в COM порт.

Никаких дополнительных данных, вроде дня недели и так далее, передавать не требуется. Только UNIX время. Всё остальное делается в Arduino.

Теперь немного конкретики непосредственно о первой составляющей – программе для Windows. Программа написана в старой-доброй Delphi. При запуске всплывающее окно просит выбрать COM порт для отправки данных. Выбираем. Остальные настройки следует оставить «дефолтными».

Как работает программа? Она пересчитывает из формата времени Windows данные для формата UNIX, то есть число секунд с полуночи 1 января 1970 года. Затем добавляет 3 секунды и «впадает» в пустой цикл (очевидно, длительностью уже менее тех самых добавочных 3 секунд), выход из которого происходит в нужное количество секунд, как можно ближе к 000 миллисекундам. Иначе говоря, отслеживается наступление самого начала той секунды времени, значение которого должно будет переслаться в Arduino. Согласитесь, пересылать данные о том, что, например, сейчас XXXXXXXXX5 секунд тогда, когда на самом деле уже, например, XXXXXXXXX5 и 756 тысячных (например) секунд, было бы не правильным. Именно для этого нужно отслеживать самое начало секунды для старта передачи данных. После передачи данных программа дружелюбно сообщает статус «Done :)». На этом миссия программы завершается.


Вторая составляющая – аппаратно-программная часть – Arduino. Существует 2 разновидности «железа» для этого проекта: «полная» версия с экраном и кнопкой, и «урезанная» версия для быстрой установки времени модуля, собранная из «г**на и палок». Про их отличия – ниже. «Полная» версия состоит из Arduino Nano, экрана 1602 с «переходником» с I2C в экран, опциональной кнопкой ресета Arduino и пин-хедера(female) для подключения модуля часов. Также, опционально, из корпуса девайса с «няшной» наклейкой. «Урезанная» версия состоит из Arduino (Uno, Nano, Pro Mini + «правильный» переходник на USB с DTR) и 4 проводов для подключения модуля часов.


Как видно из схем, «полная» версия, в дополнение к «урезанной», содержит кнопку для reset'а и экран 1602 с «переходником». Обе версии абсолютно одинаковы по основному функционалу – устанавливать время. Экран нужен лишь для отображения этапов процесса и, по окончании процесса установки времени, отображения свежеустановленных времени, даты и дня недели. Причём данные к тому времени будут уже считываться из самого модуля часов. В «урезанной» версии роль экрана выполняет встроенный в плату Arduino светодиод: по окончании процесса установки нового времени он начнет светиться. Вот и вся индикация.

Для чего же кнопка ресет? Для того, что в полной версии после установки времени Arduino войдёт в бесконечный цикл по отображению того самого свежеустановленного времени, то есть, по сути, станет часами. Причём часами, сделанными на скорую руку, в связи с чем они не смогут заменить нормальные часы в силу нескольких причин (выборка секунд реализована через delay, пропадёт отображение времени при отключении питания). Ведь цель – убедиться, что время синхронизировано верно, не более того. Следовательно, для синхронизации следующего модуля часов без ресета не обойтись (точнее, можно обойтись, если «передёрнуть» USB кабель). Другими словами, назначение кнопки – сугубо утилитарное. При желании, можно обойтись и без неё.

Как же прошивать Arduino, ведь версии «железа» две, а скетч один? Для компиляции «правильной» версии прошивки в заголовке скетча нужно установить желаемое значение параметра fullVersion: true для «полной» версии, или false — для «урезанной». Компилятор таким образом определит, для какой версии «железа» компилировать прошивку.

Итак, схема подключения есть, нужен код скетча. Обратите внимание, что для нормальной работы скетча с «полной» версией нужна библиотека LiquidCrystal I2C by Frank de Brabander (устанавливается из репозитория при помощи Менеджера Библиотек).

Вот код скетча:

//======================================== настройка, доступная для изменения ========================================

#define fullVersion true    //true = "полная" версия с экраном;  false = "урезанная" версия со встроенным светодиодом

//================================= используемые библиотеки и объявление переменных ==================================

#include <Wire.h>
#include <DS3231.h>

#if (fullVersion)
  #include <LiquidCrystal_I2C.h>
#endif

unsigned long t1 = 0;   //переменная для полученного времени
unsigned long t2 = 0;   //переменная для полученного времени
byte b[4];              //буфер для получения данных из COM порта

#if (fullVersion)
  byte day = 0;
#endif

DS3231 clock;
RTCDateTime dat1;

#if (fullVersion)
  LiquidCrystal_I2C lcd(0x3F,16,2); //китайси полюбили новый адрес для "переходников" с i2c в экран
#endif

//====================================================================================================================

void setup(){
  #if (!fullVersion)        //актуально только для "урезанной" версии - начало участка кода
    pinMode(13, OUTPUT);
    digitalWrite(13,LOW);
  #endif                    //актуально только для "урезанной" версии - конец участка кода

  clock.begin();
  Serial.begin(9600);

  #if (fullVersion)         //актуально только для "полной" версии - начало участка кода
    lcd.init();
    lcd.backlight();
    lcd.setCursor(0,0);
    lcd.print("COMport 9600 8N1");  //подсказка, какие параметры COM порта выбирать в программе
    lcd.setCursor(0,1);
    lcd.print("Ready to sync");     //сообщение статуса - готовы к синхронизации
    delay(1000);
  #endif                    //актуально только для "полной" версии - конец участка кода
}

void loop(){
  if (Serial.available()){  //если есть "порох в пороховницах" COM порта
    Serial.readBytes(b,4);  //считаем все 4 байта (другого мы и не ждём)

    t1=b[0];
    t2=(t1<<24);            //поместить значение байта в 4-байтную переменную и передвинуть его на 3 байта влево
    t1=b[1];
    t2+=(t1<<16);           //поместить значение байта в 4-байтную переменную и передвинуть его на 2 байта влево
    t1=b[2];
    t2+=(t1<<8);            //поместить значение байта в 4-байтную переменную и передвинуть его на 1 байт влево
    t2+=b[3];               //поместить значение байта в 4-байтную переменную

    clock.setDateTime(t2);  //установить полученное время на DS3231

    #if (fullVersion)       //актуально только для "полной" версии - начало участка кода
      lcd.clear();
      lcd.setCursor(0,0);
      lcd.print("Done:)    :  :");

      while (true){         //начало бесконечного цикла по отображению свежеустановленных времени и даты

        dat1 = clock.getDateTime();

        if (dat1.day != day){
          day = dat1.day;
          lcd.setCursor(0,1);
          if (dat1.day < 10) lcd.print("0");
          lcd.print(day);
          lcd.print("-");

          switch (dat1.month){  //выбираем буквенное соответствие месяца по цифре
            case 1:{
              lcd.print("Jan");
              break;
            }
            case 2:{
              lcd.print("Feb");
              break;
            }
            case 3:{
              lcd.print("Mar");
              break;
            }
            case 4:{
              lcd.print("Apr");
              break;
            }
            case 5:{
              lcd.print("May");
              break;
            }
            case 6:{
              lcd.print("Jun");
              break;
            }
            case 7:{
              lcd.print("Jul");
              break;
            }
            case 8:{
              lcd.print("Aug");
              break;
            }
            case 9:{
              lcd.print("Sep");
              break;
            }
            case 10:{
              lcd.print("Oct");
              break;
            }
            case 11:{
              lcd.print("Nov");
              break;
            }
            case 12:{
              lcd.print("Dec");
              break;
            }
            default:{
              lcd.print("???");
              break;
            }
          }//switch month

          lcd.print("-");
          lcd.print(dat1.year);
          lcd.print(" ");

          switch(dat1.dayOfWeek){   //выбираем буквенное соответствие дня недели по цифре
            case 1:{
              lcd.print("Mon");
              break;
            }
            case 2:{
              lcd.print("Tue");
              break;
            }
            case 3:{
              lcd.print("Wed");
              break;
            }
            case 4:{
              lcd.print("Thu");
              break;
            }
            case 5:{
              lcd.print("Fri");
              break;
            }
            case 6:{
              lcd.print("Sat");
              break;
            }
            case 7:{
              lcd.print("Sun");
              break;
            }
            default:{
              lcd.print("???");
              break;
            }
          }//switch dayOfWeek
        }//if date changed

        lcd.setCursor(8,0);
        if (dat1.hour < 10) lcd.print("0");
        lcd.print(dat1.hour);

        lcd.setCursor(11,0);
        if (dat1.minute < 10) lcd.print("0");
        lcd.print(dat1.minute);

        lcd.setCursor(14,0);
        if (dat1.second < 10) lcd.print("0");
        lcd.print(dat1.second);

        delay(995);
      }//while
    #else                       //актуально только для "урезанной" версии - начало участка кода
      digitalWrite(13, HIGH);
      delay(3000);
      digitalWrite(13, LOW);
    #endif                      //актуально только для "полной" версии - конец участка кода
  }//if Serial
}//loop


Пара фото «полной» версии готового девайса.


Ну и, наконец, видео работы девайса «в бою»:


Где скачать скетч и программу?

Скетч качать здесь (Dropbox).
Программу для Windows качать здесь (Dropbox).

«Плюсы» и «минусы».

Сформулировать «плюсы» и «минусы» в данном случае тяжело. Следовательно, каждый решает для себя сам, что – хорошо, а что – плохо.


Итого.

Мне очень понравилось, как теперь устанавливается время в модулях! При необходимости установить время мне не приходится вспоминать каждый раз, какой же там скетч мне нужен и задумываться, насколько точно будет установлено время в модуле. Более того, скоро будет обзор самодельных часов, куда я встроил такой метод синхронизации – настолько метод мне понравился. Надеюсь, кому-то из читателей метод также придётся кстати.

Проект — свободный, некоммерческий. Каждый вправе использовать данные из обзора в любых целях, кроме коммерческих.

Всем добра.
+
avatar
  • sshiva
  • 01 февраля 2017, 08:47
0
Не очень полезно, но качественно и грамотно :)
+
avatar
0
обалдеть, сколько материала изучено и любезно вывалено по такой казалось бы простой задаче — выставить часам верное время.

Я ограничился подключением дисплея параллельно часам + 3 кнопки чтобы выставить время ручками. когда допривинчиваю WiFi, время будет само синхронизирвоаться с каким нить сервером, ну а пока кнопки.
+
avatar
+8
Ставим модуль esp8266 подключаем к нему модуль часов, есп устанавливает время интернета в модуль часов. Бинго))

Можно просто прибор собрать на есп, тогда он сам будет синхронизиррватся если есть wifi.
+
avatar
0
где бы поучиться работе с этим модулем? Если с ардуинкой ещё кое как работается и инфы структурированной много от начального уровня до более менее сложных проектов, то на ЕСП я вижу только уже сложное. может подскажете чего?
+
avatar
+1
wifi-iot.com

Конструктор прошивок на esp8266

С простыми модулями бесплатный, с эксклюзивными экранами 100р. но это того стоит.

тут были обзоры esp8266 с прошивками и пошаговой инструкцией главное залить первую прошивку. остальные заливаются по wifi))
+
avatar
  • Angrim
  • 01 февраля 2017, 09:40
+1
Под esp8266 есть ардуино ide, раз уж так нравится ардуино, esp8266.ru там все есть. Рабоется с ними как с теми же ардуино в той же оболочке
+
avatar
  • Sprite
  • 01 февраля 2017, 09:40
0
Можно поподробнее?
+
avatar
  • jenya
  • 01 февраля 2017, 08:56
+2
date '+%s' >/dev/ttyS0 (ну или какой там номер порта )
+
avatar
  • sir0ta
  • 01 февраля 2017, 09:26
0
Скетчки выкладывать надо на гитхабе и иже с ними. С дропбокса завтра 100 человек скачают (а то и меньше на фришном ТП) и заблокируют файл…
+
avatar
  • iDDD
  • 01 февраля 2017, 09:28
+7
Помнится, в какой-то советской еще книжке для юных радиолюбителей, за тысяча девятьсот восемьдесят лохматый год, попадалась схема электронных часов (что по тем временам уже само по себе было уровнем, скажем так, выше среднего) с синхронизацией (!) по сигналам точного времени радиостанции «Маяк».

Ежедневно, незадолго до 12 часов дня схема включала приемник и слушала эфир. Конструкцией из монструозных RC-фильтров и логических счетчиков, собранных едва ли не на реле и лампах, выделяла «начало шестого сигнала соответствует 12ти часам московского времени», по которому и корректировала часы.

Тогда это казалось вершиной прогресса и творческой мысли, в целом решение весьма изящное и привлекательное своей автономностью. И я, будучи школотой, у которой элементная база состояла лишь из того, что удавалось выпаять из притащенного с помойки хлама, взирал на нее с благоговением и мечтал, что когда стану взрослым дяденькой, всенепременно соберу такие часы. Сейчас попробовал загуглить ту схему, а поисковик выдал современный аналог из микроконтроллера и пары резисторов — скукота, тоска и увеличение тлена, где мои теплые ламповые лампы и МП42, я вас спрашиваю? Да и если у тебя в детстве не было велосипеда, а сейчас есть порш, то все равно у тебя в детстве не было велосипеда.

К чему все это, да просто минутки ностальгии камент. Передаю радиолюбительский привет всем пионерам, чье детство прошло под запах канифоли)
+
avatar
  • Dimon_
  • 01 февраля 2017, 09:36
+4
и МП42
Так ведь МП26Б же, они были распространённее :). И МП37, без npn никуда.
А у 42-х спиливали шляпку, чтобы получить фототранзистор :)
+
avatar
  • kalobyte
  • 01 февраля 2017, 09:39
0
теперь у тебя есть шанс собрать супергетеродин на 75кгц для приема цифрового сигнала точного времени
приемник прямого усиления работает только в пределах германии и то не всегда
+
avatar
  • ABATAPA
  • 01 февраля 2017, 09:41
0
Даже сейчас есть часы (в том числе и наручные), синхронизирующиеся по DCF77. Даже тут обзоры были, ищутся поиском.
+
avatar
  • Vipeg
  • 01 февраля 2017, 10:12
0
Да и если у тебя в детстве не было велосипеда, а сейчас есть порш, то все равно у тебя в детстве не было велосипеда.
Прекрасно сформулировано. Пожалуй, запишу это выражение где-нибудь на память :)
+
avatar
  • Dimon_
  • 01 февраля 2017, 09:33
+3
между модулем часов и компьютером – чуть ли не единственным способом выставить время более или менее точно.
Мягко говоря, это не очень так :)
Уже проектах в пяти я реализовал для себя простой и действенный способ: я забираю время с GPS. Точность такого времени значительно выше, чем точность NTP. Дешёвейший модуль с Али ловит спутниковое время даже в центре панельного дома в глухих бетонных городских дебрях. Ардуиной разбираю символьный поток, оцениваю ошибку и, если она меньше заданного порога, синхронизирую время. Полная автономность и независимость от компьютера. И от скачков и провалов питания, кстати.

что самое важное в любых часах? Разумеется, это точность хода.
Помнится, меня на этом ресурсе как-то люто заминусовали за это утверждение в одном из многотысячных обзоров наручных часов :)
Мне доказывали, что сейчас, йоу, часы — это чисса модный аксессуар, что их главная функция — имиджевость и стильность, а время для наручных часов — ващще не главное.
+
avatar
  • klop
  • 01 февраля 2017, 09:34
0
Тоже раньше так делал, когда впервые познакомился с RTC на DS3107. Жутко неудобно. Теперь просто сделал часы (4x-разрядный индикатор + 8 резисторов (60 руб), arduino mini (100 руб), IR датчик (4 руб) и DS3231(31 руб)), написал скетч и выставляю время с IR пульта. Кроме того ввел автовычисление погрешности по 2-м замерам и получил мегаточность (причем коррекция времени ежесекундная). Теоретическая точность 1 сек в 68 лет (практическая зависит от интервала между замерами, стабильности кварца и жизни батарейки). Кстати, в моих часах можно использовать и древний DS3107 (лишь бы тот врал стабильно) примерно с таким же результатом.